微信多开程序（附代码）

@echo off
chcp 936 >nul
title 微信多开启动器 by 瑶404
color 0a
echo ****************************************************
echo *         微 信 多 开 启 动 器（高 级 版）         *
echo ****************************************************
echo.

if "%~1" neq "" (
    set "WECHAT_PATH=%~1"
    goto :found
)
taskkill /F /T /IM WeChat.exe >nul 2>&1
for %%r in (
    "HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\WeChat"
    "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\WeChat"
    "HKLM\SOFTWARE\WOW6432Node\Tencent\WeChat"
    "HKLM\SOFTWARE\Tencent\WeChat"
) do (
    reg query "%%~r" /v "InstallLocation" >nul 2>&1
    if not errorlevel 1 (
        for /f "tokens=2*" %%a in ('reg query "%%~r" /v "InstallLocation" ^| find "InstallLocation"') do (
            if exist "%%b\WeChat.exe" (
                set "WECHAT_PATH=%%b\WeChat.exe"
                goto :found
            )
        )
    )
)

:notfound
echo 抱歉，未找到微信主程序！
echo.
echo 请将微信快捷方式或主程序拖放到本窗口（需删除引号）
echo 或者手动输入微信主程序 WeChat.exe 路径
echo.
set /p WECHAT_PATH="请输入路径（或直接回车退出）: "
if "%WECHAT_PATH%"=="" exit
if exist "%WECHAT_PATH%" goto :found
echo 输入的路径无效！
pause
exit

:found
echo 已定位到微信路径: %WECHAT_PATH%
echo.
set "COUNT=2"
echo 请输入要开启的微信数量(1-9)
echo.
echo 直接回车将启动2个微信（5秒后自动运行）
echo.
choice /c 123456789 /n /t 5 /d 2 /m "输入数量(1-9): "
if not errorlevel 255 (
    set "COUNT=%errorlevel%"
)

:launch
echo @echo off > "%temp%\launch_wechat.bat"
for /l %%i in (1,1,%COUNT%) do (
    echo start "" "%WECHAT_PATH%" >> "%temp%\launch_wechat.bat"
)
echo exit >> "%temp%\launch_wechat.bat"
start /wait "" "%temp%\launch_wechat.bat"
del "%temp%\launch_wechat.bat"
echo.
echo 成功启动 %COUNT% 个微信！
echo.
echo 感谢使用！
echo.
echo 本窗口将自动关闭！
timeout /t 2 >nul
exit